Civs sollen Cops Tasern

Moin ich habe jetzt viel Rumprobiert das Civs Cops Tasern können doch alles Erfolgslos.
Weiß jemand wie das in der 5.0 einzustellen geht?
MFG

Zitat von moeck

ja du musst das in der fn_handleDamage.sqf anpassen

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_handleDamage.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Handles damage, specifically for handling the 'tazer' pistol and nothing else.
*/
params [
    ["_unit",objNull,[objNull]],
    ["_part","",[""]],
    ["_damage",0,[0]],
    ["_source",objNull,[objNull]],
    ["_projectile","",[""]],
    ["_index",0,[0]]
];

//Handle the tazer first (Top-Priority).
if (!isNull _source) then {
    if (_source != _unit) then {
        if (currentWeapon _source in ["hgun_P07_snds_F","arifle_SDAR_F"] && _projectile in ["B_9x21_Ball","B_556x45_dual"]) then {
            if (side _source in [west,civilian] && playerSide in [west,civilian]) then {
                _damage = 0;
                if (alive player && !life_istazed && !life_isknocked && !(_unit getVariable ["restrained",false])) then {
                    private ["_distance"];
                    _distance = 35;
                    if (_projectile == "B_556x45_dual") then {_distance = 100;};
                    if (_unit distance _source < _distance) then {
                        if !(isNull objectParent player) then {
                            if (typeOf (vehicle player) == "B_Quadbike_01_F") then {
                                player action ["Eject",vehicle player];
                                [_unit,_source] spawn life_fnc_tazed;
                            };
                        } else {
                            [_unit,_source] spawn life_fnc_tazed;
                        };
                    };
                };
            };

            //Temp fix for super tasers on cops.
           // if (side _source isEqualTo west && (playerSide isEqualTo west || playerSide isEqualTo independent)) then {
           //     _damage = 0;
           // };
        };
    };
};

[] spawn life_fnc_hudUpdate;
_damage;

Alles anzeigen

Vielen Dank moeck

Das ist richtig!